Chapter 3

[i][b]A long time ago…[/b][/i]

"Why did you come here, Quinn? This is my punishment."

It's nice that ${q_he}'s here but that doesn't mean I understand ${q_his} reasons. It was my doing to be here, my punishment alone to suffer.

A sigh escapes me as I rub the back of my neck. 

*if calm_child
    Mother didn't like my 'lethargic' way of chanting, as she called it. My mind was elsewhere. She expects the most from me, more than from my siblings, and I can't help but to feel that I'm letting her down.
*if brazen_child
    Mother didn't appreciate when I answered her every question about the Twins with 'who really knows the will of the gods, I am but a mere mortal'. I, at least, thought it was funny. And it's true, too.
*if empathetic_child
    Mother didn't appreciate that in the middle of a chanting session I stopped to help a trapped grasshopper in its peril. Its feet were glued into a resin of a tree, I had to take my time in order to free it. I did succeed and the little guy hopped to its freedom.
    
    However, mother remained unimpressed. 
*if imp_child
    I couldn't bear another boring lecture of the Twins, and eventually mother found me wandering in the forest. I tried to escape onto a tree, but she caught me just in time, pulling my foot and shouting a string of curses. She's faster than she looks.
    
Quinn wipes ${q_his} raven-black hair out of ${q_his} line of vision and gives me a small, subdued smile. "You would be alone here. It's already dark." 

A croak of a raven cuts through the silent night, announcing us of its existence. The air in the grove is heavy, but not unpleasant. 

It's never unpleasant.

"Is that a reason enough to spoil your evening, too?"

$!{q_he} just smiles and continues ripping the weeds out of the ground. $!{q_his} hands are already muddied, ${q_he} works swiftly, gently pushing me aside when I try to tear my share of the weeds. My palms remain clean.

"Just let me do my part!"

"No." $!{q_he} smiles, and I find it useless to argue back. The situation has repeated its course for too many times. So I sit down on the moss and watch ${q_him} work.

Only the sounds of ${q_his} puffing fills the otherwise silent early night. The roots are deep beneath the ground and mother offered no tools.

"We would've been home by now, if you just let me help," I say with a shake of my head.

"Shut it."

Suddenly ${q_he} stops working and turns ${q_his} gaze to the now black sky, already cluttered with little stars.

"$!{name}… Do you think the gods take the dead with them? Do they reside in the stars, looking down on us?"

I glance at the sky. $!{q_he}'s talking about ${q_his} family.

*fake_choice
    #"Of course."
        *set ch3_dead_yup true
        Quinn turns to me with a big, relieved smile. Fresh tears gather in the corners of ${q_his} eyes but I pretend I don't see them. $!{q_he} turns his gaze back to the stars as a lone tear creeps its way to ${q_his} cheek. I'd wipe it away but that would only embarrass ${q_him}. So I merely smile back to ${q_him}.
        
        "I trust you," ${q_he} whispers and squeezes ${q_his} fist tight. "You know about these things. I trust you," ${q_he} repeats the sentiment.
        
        I give ${q_him} a reassuring smile with a nod. Perhaps it's a matter of faith but I do believe that the dead are looking down on us. I don't have anyone close to me dead, so I haven't really thought about these things. But in my heart I believe the gods take good care of the dead, high above the stars.
    #"I don't know."
        *set ch3_dead_dunno true
        Quinn turns to me with ${q_his} brows knitted. "You're not sure?" 
        
        I don't have the heart to lie to ${q_him} when I myself am not sure of the fate of the dead. I should believe in the gods and their power, mother would say. I should [i]know[/i] what happens. But who really knows what happens after death? So I shake my head to confirm my uncertainty.
        
        Quinn's gaze drops to the ground, away from the stars. The gesture almost makes me take back what I said, to reassure ${q_him} that maybe they are there. Maybe they are among the stars with the gods. Maybe those who have lost someone really just need some comforting words, no matter the truth behind the words.
        
        Perhaps. But as Quinn's eyes gather a fresh set of tears, I realize it's too late to take my words back. There's only heavy silence lingering between us as ${q_he} gets back to work.
    #"No."
        *set ch3_dead_nope true
        $!{q_he} frowns as his gaze is still lingering on the stars. "How can you say that?" There's anger in ${q_his} voice, something I wasn't expecting.
        
        "Who really knows what happens after death?" I defend my harsh truth and look at the stars. Why would they be there? Why wouldn't they just be dead in the ground, that's where everyone ends up in.
        
        "Don't you think I want to hear that they're there? Don't you think it would ease my burden? That when I think about them, I wouldn't have think that they're nothing but a pile of bones, a lump of rotting flesh, their spirit lost? Their touch forever gone from my grasp, their voice muted, their visage only a fainted memory that will distort over time." $!{q_his} words are bitter, ${q_his} breathing quick, the glimmering in ${q_his} eyes a tell-tale of tears.
        
        "I'm sorry," I quickly take my words back, but it's too late, ${q_he}'s already shut down and is back to work. Heavy silence lingers between us.
        
Pity raises its head within me as I look at my friend deep in thought, ${q_his} lips pursed, ${q_his} jaw clenched, ${q_his} mind clearly distraught and filled with pain.

I wish I'd never have to know the pain ${q_he}'s going through.

*page_break
[b][i]Present day[/i][/b]

After the day of marching routines, Marcus wanted to see me in his office. To think that just a few months ago the thought of entering his office would have raised every alarm bell in me. Now, it's a day like any other.

For my surprise, the 6-year-old girl from before is standing in front of the door. Before I can ask, she hushes me into silence with her index finger. She beckons me to press my ear against the door, as she was doing before I interrupted her. 

*fake_choice
    #Press my ear against the door, as well.
        *set ch3_door_ear true
        I nod and lean in against the door. It's a bit childish, but this way I can hear better. There are heated voices on the other side.
    #Gesture that I can hear just fine without the antics.
        She sticks her tongue out at me and presses her ear back on the door.

"I already applied for your transfer to Rome. You will work as a Praetorian Guard."

The Legate.

"You can't make that decision for me."

"I can and I will. I have tolerated your rebelling long enough. You're pushing forty, you can't just waste your life away here. You need to continue our family line and be in a respectable position—"

"Your daughters already provide you with heirs, take care of their well-being for a change."

"They're fulfilling their duty as they should. You're the only one who keeps fighting."

"Duty!" Marcus bawls so loudly I almost jump. A couple of officers peek from the corners of the hallway to see what the commotion is. Their eyes meet mine and quickly leave the scene as Marcus keeps roaring: "Duty to be sold like cattle to the most influential politicians to further your own goals!"

A third voice steps in, her tone amicable and gentle: "Calm down, you two. You're scaring—" 

"Silence!" The Legate shouts. "You will stop this madness and you will come back to Rome with me. The only son of mine will not die on the front lines with—"

"With what?"

"You know." A heavy pause. "It's not even Legionaries you're leading. The Senators keep asking why my son is so keen to lead those—"

"Barbarians."

Silence ensues, and only the angered breathing of Marcus can be heard in the now empty hallway. He's the Legate's son?

The girl peers at me and gives me a serious shake of her head. "You're not a barbarian."

"Thanks, kid." 

*page_break 
I need to leave before Marcus sniffs me out.

Just as I'm planning my quick escape, the door 
*if ch3_door_ear
    hits me in my face with such force I fly backwards and land on my bottom. 
    
    Thankfully the girl managed to evade the impact. "Hati!" She shouts and hurries to give me the palm of her tiny hand, as if she'd have any strength to help me up.
    
    Marcus gives me a small raise of an eyebrow, as if blaming me for the incident.
*if not(ch3_door_ear)
    almost hits my face. The girl was thankfully nimble enough to evade the impact. 
    
    Marcus gives me a small raise of an eyebrow.
He examines me with his chest still rising in agitation. His voice is steady, if not slightly hoarse: "Do come in, soldier."

Of course he knew I'd be here. He can smell me.
*page_break

I follow him inside, what else can I do. The room is heavy with hostility, the two clearly aggravated high-ranking officers staring each other down. Marcus, however, is the more hostile one. There's an unknown woman, too, who spares me a quick glance before her gaze is captured by the girl. 

"Antonia, come here." She beckons the child. The woman's dark hair matches Marcus's in color. The girl, Antonia, runs to her and keeps her eyes on the two officers. She's not afraid of the conflict. She has a glimmer in her eyes as she waits for the argument to continue.

Marcus proceeds to gesturing at me as if presenting a prize pig: "Behold, a barbarian you're so sneering at."

Great. This is a full-blown family feud and I'm being dragged straight into it.

The Legate's gaze quickly swifts to mine before darting away. "I didn't mean that the lad is any less—"

"He's fighting for Rome as any of the other men outside. He [i]is[/i] Roman."

My whole being wants to shout 'as if'.

Legate flushes red with a deep frown and gazes at me before turning his eyes back to the ground. "I'm sorry you heard that," he says, "and I'm sorry for saying it. I cannot defend my insulting words. Of course you Britons are Romans. You're as much a Roman as I am."

Oh, but you're wrong. I'm not a Briton at all, nor Roman, for that matter. I am a filthy, painted barbarian.

*fake_choice
    #"I forgive you, Lord Legate." As if I would forgive anything.
        *set manipulative +1
        *set legate_friendship +2
        I quickly try to diffuse the somewhat embarrassing situation. Nowadays I rarely take offense over the term barbarian, or the silent sneer followed with the term. I don't care. They can think of me however they like to. That's the least of my worries.
        
        The Legate gives me a quick smile, his hand twitching towards my head. Thankfully, however, he halts his wandering patting hands. "You're a good boy." He says, as if talking to a dog, and shakes his head. "Too good. But I will make this up to you."
    #"I don't care what you call me, Lord Legate." It's the truth. As if insults would wound me anymore than these people already have.
        *set manipulative -1
        His brows knit just a little, as if he's pondering the weight of my words. But then he shakes his head. "I care. I'm a disgrace, to call my own men like this."
    #Say nothing and look him in the eyes with defiance.
        *set legate_friendship -1
        *set brazen +2
        At first, I tried to say something. Anything to make him not unnecessarily aware of me. But he wants me to forgive him? 
        
        Ha! So I merely stare at him. The creases on his face deepen. His mouth opens, as if he's about to say something, but he thinks better of it and drops his gaze to the ground. "I will make this up to you, my boy." He nods to me and takes his leave.
    #Remain silent.
        If I remain silent, perhaps I can slip away sooner rather than later. This is highly awkward.
        
        The Legate gives me a quick, apologetic smile. "I'm sorry I made you uncomfortable." 
        
With a nod he takes his leave, almost fleeing the office. When the groaning door shuts behind him, the woman shifts uncomfortably. Her dark eyes are aimed at Marcus as she finally sighs. "I'll take my leave, too. Please don't dwell on this." She bids us goodbye and leaves with a hurried step with reluctant Antonia.

Marcus slumps on his golden embroidered sofa, his hands shielding his eyes as he almost groans. "You heard all of it?"

"Most of it, Lord Centurion." 

He frowns behind his hands, even though I'm sure he knew. "You'd best forget about that. I asked you here to fetch me another package." 

I nod.

He looks like a corpse, lying on the sofa with his arms and legs limp. It's quite a theatrical sight.

*label ch3_youaightthere
*choice
    #Ask about his sisters.
        *set marcus_friendship +3
        "Can I ask, Lord Centurion?"
        
        He mutters under his breath as an answer, but doesn't outright deny the request. As far as I can hear, at least.
        
        "You have sisters?"
        
        He turns to me with slightly squinted eyes, as if contemplating whether to answer or not. Then, he dives back behind his palms and says: "…Yes."
        
        "How many?"
        
        "Five. No brothers."
        
        "That's… nice?"
        
        He takes his hands from his face and almost rolls his eyes. "Do you know the weight Roman patricians give to their daughters?"
        
        I can't say that I do, but I've heard stories about how situation changed in Britannia after Rome. Fewer women in respected offices than before, no women allowed in the army.
            
        "I…" Finally he stands up and moves back to his desk. He takes a colorful bracelet and starts fiddling the beads. Then he turns to me, by now wearing the same smug grin he always does. "Why do you care, anyway? Don't tell me you're growing soft on me?"
        *goto ch3_office
    *disable_reuse #"You're looking quite dramatic, Lord Centurion."
        He merely scoffs behind his palms and remains lying there. It seems he's not in the mood for sparring. 
        
        Weird.
        *goto ch3_youaightthere
    #Remain silent.
        He remains lying there for a good while before evidently realizing that I'm still standing here.
        
        "What are you still doing here? Shoo."
        
        "You asked me here, Lord—"
        
        "Now I'm asking you to leave, you little moron. I gave you a task and now you need to leave."
        *goto ch3_office

*label ch3_office
*choice
    #Leave the office.
        I leave with the groaning door marking my departure. That was a little more family drama that I was prepared for this early in the morning.
        
        "Hati? What a nice surprise, I was just looking for you." Niall appears from the hallway with an easy smile. His purple tunic hangs lazily on his muscular frame, as if he just woke up and threw something on him with little care.
        
        "What is it, Lord Tribune?"
        
        "Follow me to my office, if you please."
        *goto ch3_reading?
    #Stay a little longer. I need to ask him something.
        *goto ch3_cockpunch

*label ch3_cockpunch
*set cockpunch true
*fake_choice
    #Ask what happened in the forest.
        "Lord Centurion," I say, still hesitant about what happened. He raises his gaze expectantly, clearly hearing that my words bear a heavy topic. "Did anything weird happen in the forest? With Quinn?"
        
        If I didn't know any better, I'd say mentioning ${q_his} name makes a light shudder run through him. I could be imagining things.
        
        "You fainted," he states as if I'm annoying him with the subject. "That's all that happened. I don't know why you insist on dwelling in that. If I were you, I'd try to make people forget about that embarrassment."
        
        "But—"
        
        "Soldier, you're beginning to annoy me."
            
        Well, I certainly wouldn't want that.
        
        *if marcus_voices
            He squints his eyes at me, inspecting me with his penetrating gaze. "First you said that you hear voices, now you're fainting about. It doesn't seem like you're fine at all."
        
            I quickly shake my head, trying to banish him from scrutinizing me. "I am fine, Lord Centurion."
        
        He stands up and takes a step towards me, his gaze still scrutinizing me. "Are you quite sure you're alright?"
        
        I remain in place, bracing myself for his antics.
    #On the other hand, it's better not to ask.
        He already told what happened from his viewpoint, I doubt I'd get anything more out of him. More sneer, if anything.
        
        "What? You look like you want to say something."
        
        "Nothing, Lord Centurion."
        
        He squints his eyes. "What are you still doing here? Do you want to know about my family history? Do you want to know me?"
    
Suddenly a high-pitched voice from the height of our thighs yells: "COCKPUNCH!"

Marcus's face distorts into what could only be described as having your crotch punched by a 6-year-old. He bends over as Antonia stands over him, her little hand clenched into a fist. She's like a champion of the gods as depicted in the many statues littering the town. She's conquered the monster.

"You're a big meanie, Uncle."

Or the big meanie.

*fake_choice
    #Laugh.
        *set antonia +1
        I can't help it, I don't know if I even want to. It's almost too sweet to hear Marcus trying his best to express his anger but managing to only produce a pitiful groan.
        
        "You dare to laugh, you little—"
        
        "You want another round, Uncle?" Antonia sneers at the downed beast of a man. Marcus quickly shakes his head and stays down.
    #Ask Marcus if he's okay.
        *set ruthless -1
        *set marcus_friendship +1
        I don't know why I would care, the question comes out more as a reflex than anything. Perhaps the sound of his pained yell was too much even from his lips, maybe I'm too soft for my own good. He nods quickly, trying to compose himself as best as he could. It's not much: his hands are still hovering over his pelvic area, his features distorted. 
        
        Antonia pouts. "He deserved it. He was being mean."
        
        I almost agree with her but stop myself in time. I'm not sure if it's a good thing to teach children that they should punch people if they're being mean. In their crotch, no less. Perhaps not, I'm not the expert.
    #Try to reprimand Antonia. Also, try not to laugh while doing so.
        *set antonia +1
        "That's not nice, Antonia. You can't just go punching your uncle in the crotch like that." I try to keep a straight face, but I'm not sure if I'm doing a good job at it.
        
        The girl reads my expression like a little lynx she is before giving me a conspiratory smirk. "Uh-huh. Right."
    #Thank Antonia.
        *set antonia +2
        "Thank you, Antonia," I say and give her an approving nod. She gives me the brightest beam her little features can hold. Marcus groans louder, clearly trying to express his disappointment over our newly found alliance.
        
        "You little—"
    #Remain silent.
        I merely watch the unfolding scene, my features expressionless as Marcus tries to get up. I suppose I could try to help him, but he did deserve the punch.

Finally Marcus gets up, clearly trying to hide any remaining pain still lingering from the surprise assault. "Antonia," he says in a low voice, any trace of authority undermined by the fresh tears of pain in the corners of his eyes.

Antonia raises her chin, ready to meet her fate. She clenches her fists again, as if ready to punch again if need be. Marcus flinches and his gaze quickly turns to me. Then he looks away, clearly not sure how to act in this situation. 

"Have you seen Antonia? She ran off to—" Niall's voice cuts the tension. He's left standing in the doorway, his gaze examining the scene. Then, he sighs. "Did you cockpunch your uncle again, dear?"

Antonia nods. "I did what I had to. He was bullying Hati."

"Oh." Niall turns his gaze to me, then back to Marcus. "In that case, good job!"

Antonia beams before turning to me. "You can call on me if he tries anything."

I seem to have a guardian angel at the ready to punch my enemies' crotches.

*page_break
"Hati, I had something to ask of you," Niall says and gestures me to follow him.

"Take the child with y—" Marcus starts, but Niall closes the creaking door with haste before Marcus can finish his sentence. It's hard to say if Niall heard the plea and chose to ignore it, or if he's in his own thoughts. His features give nothing away, he merely gives me a small smile and starts walking toward his own office.
*goto ch3_reading?

*label ch3_reading?
*if niall_office
    As he opens the door to his office, a familiar strong whiff of herbs greets with my nostrils. It seems he has stacked even more herbs since the last time I was here. The ceiling is half filled with them. I have to dodge bouquets of herbs to get to his desk.
    
    This is starting to look more like a herbalist's office than a Tribune's.
    
*if not(niall_office)
    As he opens the door, a surprisingly strong whiff of flowers and herbs greets my nostrils. Drying herbs and flowers decorate the walls and the ceiling of his spacious office. The ceiling is half filled with them. I have to dodge bouquets of herbs to get to his desk.
    
    This looks more like a herbalist's office than a Tribune's.
    
He sees my slightly judging expression and gives me a small shrug. "I don't have room in my home anymore." I raise my brows and he continues: "Um. Yes. I'm not hoarding these, this is just me preparing for winter."

"I see."

He sits behind his desk and shuffles the scrolls in front of him. He's not reading them, nor re-arranging, he's just shuffling. Then, he asks: "You know how to read, right?"

"Of course."

He shakes his head and frowns at one of the scrolls. "It's not a matter of 'of course'. How many in your contubernium even knows Latin? They're from the countryside, right?"

"Yes. Um." It's been a problem from time to time, when the Legate refuses speak in Celtic and sticks to Latin. The commands are difficult to understand for most of the fresh soldiers. He knows it, he enjoys it, it's a whole another level of bullying.

Niall nods with a knowing mouth-shrug. "You can even write, right?" 

I nod.

"I'm contemplating on giving you a promotion. How would you like to be a scribe?"

*fake_choice
    #Nod. Why not.
        A scribe? Why not. It would mean getting some time away from the Optio.
        
        He beams and nods.
    #Shrug. "I don't care."
        "Oh," he says, clearly expecting me to be a bit more enthusiastic about this than I am. "Well, then I will decide for you and you will become a scribe!" 
        
        I shrug again. I really don't care how I use my time here.
        *if hatred = "determined"
            I just need to find out how to execute my plans.
        *if hatred = "confused"
            I'm just trying to survive.
    #Remain silent.
        He waits for my response, but when nothing emerges, he nods enthusiastically. "You will become a scribe!" 
    #"I don't like the sound of that." Scribe work doesn't sound too appealing to me.
        "Oh?" He looks surprised. He straightens his posture, as if trying to appear more authoritative. "I have decided that you'd be a good fit for a scribe. I'm, um… commanding you."
        
        Yes, nothing says command like phrasing it into a question.
        
"What would I do as a scribe?"

"Inventory, mostly. I would also dictate some letters for you to write."

Doesn't sound too difficult. I suppose that's as good as any job here. But before I leave… 

"Lord Tribune, one more thing. Why did you order Quinn to join us for the hunting trip?"

He knots his brows. "Who is Quinn?"

*page_break
I close the door behind me and sigh. He doesn't know Quinn. Why did Quinn lie? Did ${q_he} just want to join the trip? 

What if Marcus finds out? What if he has already? 

Quinn is playing a dangerous game.

*fake_choice
    #I'm worried about ${q_him}.
        I can't help but frowning as I ponder on ${q_his} games. I suppose I shouldn't wonder why ${q_he}'s so keen on endangering ${q_his} life. I suppose we both are.
    #This situation is quite terrifying. The voice, Quinn scheming about, the constant threat to my life.
        I sigh. It's a deep, tired sigh. It makes its way out of me from deep within, bearing the worry and fear I feel about this all.
        
        I really need to talk about this to ${q_him}.
    #I shake my head. What happens, happens.
        I'm sure ${q_he} knows what he's doing. I'm too tired to overthink things.
    #What if Quinn acted under a different name?
        That might be true. That does beg the question as to why Niall would want ${q_him} to join the hunt. I shake my head.

Another task from Marcus awaits. It's starting to feel like I'm his personal courier.

*page_break
[b][i]At the forum[/i][/b]

Just as I'm about to enter another store Marcus asked me to visit, I'm drawn in by the commotion caused by at least a hundred of people gathered in the Forum. Everyone's gazes are drawn in by the stage of sort.

What's happening here?

"Hati! What a wonderful surprise. Did you come to see the trial?" I turn to see a familiar woman beside me. 

Tinsae. She gives me a dashing smile, as if she's happy to see me.

"What is this about?" I peer at the stage where a man clad in the whitest toga I've ever seen. There are two other men with him at the stage, clad in a toga as well, but not nearly as white.

"It's about a—" She starts, but someone beside us hushes her into silence. She bites her painted upper lip before giving the husher a polite smile. 'You will see,' she mouths me.

And so the man in the whitest toga begins spouting booming words from his mouth.

*page_break
The shouting man — a lawyer — keeps shaking his fist at the sky, at the audience, opening his palm and looking at it quite theatrically. The audience acts according to his gestures; sometimes there's a loud 'ooh', a 'boo', or other miscellaneous noises. The man is controlling the audience with his hand and his exaggerated expressions.

I take a peek at Tinsae, who observes the trial with a neutral expression. She doesn't follow the man's cues of the audience, only a polite smile appears from time to time when the lawyer tries to provoke feelings of sympathy within the audience.

The case is about two feuding men who keep destroying each other's property, and finally one of their family members was found dead in the streets. A cycle of revenge. "As you already know, my client, quite naturally and understandably, placed a curse on the man's family. Who among us wouldn't do that?" There are more than a few nods, evidently from people keen on cursing others. 

The lawyer then points at the accused: "And in return, this vile man defiled his crops! I will not go into detail about the mess that was caused, but rest assured the sight was horrendous. Now, my client has to survive the winter without his crops." 

Then, the lawyer says something that catches my attention: "Not only that, but this absolute villain of a man destroyed the property my client had just acquired far away from North!"

From the corner of my eye I see Tinsae darting her gaze at me.

An echo of 'ooh's travels through the audience as the pit of my stomach start falling. "From the faraway land of the painted barbarians with a massive amount of gold and silver, my client had the fortune of purchasing a wild Pict. It was a ferocious beast! My client had so much he wanted to with this new property of his. Maybe it would've performed in the great Flavian Amphitheater, how my client's heart would've danced with joy to see such a miracle! But, alas, its life was cut to a short because of this villain!"

A… Pict.

[i]It.[/i]

[i]It[/i] was a wild Pict. And he murdered [i]it[/i].
*page_break
I barely notice that Tinsae is repeating my name.

How it didn't dawn on me sooner, I don't know. For some reason all of my thoughts have been on the ones that were murdered. But of course, most of them were enslaved. Just like the Pict who was murdered in a foreign land. Perhaps I knew them. I must have. My people are slaves to the Romans. They're nothing but furniture to the hateful creatures who took the lives of their loved ones, their homes, their freedom.

"Let's move away from the crowd." Tinsae says and takes a soft but stern hold of my hand. I don't find a will to deny her, and I'm led away from the noise and the shouting lawyer.

As little diblets of water sprinkle on my skin, I take an uninterested notice of the fact that Tinsae took me to a nearby fountain. She guides me to sit down with a gentle touch, as if afraid I'd shatter on the ground if handled with too much strength.

There are so many of us that could be slaves right now, but the ones occupying my mind are the twins. What if they're somewhere in Rome right now, doing who knows what they're forced to do? What if they're struck down like that slave, not a care given about their life, their worth, nothing. Like an object to be defiled and destroyed. I swore to protect them and they took them.

No.

The stomach acid rises to my mouth and I bent down in a hurry, spitting the sour liquids of my belly. It's not yet a vomit, but it's not for the lack of trying.

Then, a hand touches my shoulder, rubs my skin lightly with her thumb. The gesture is sudden, surprising, and takes my mind away from my physical peril.

Tinsae.

*fake_choice
    #Let her comfort me.
        *set tinsae_friendship +1
        I close my eyes and try to ground my mind into her touch. I focus on the slow, delicate movements dancing on my skin. She moves her hand onto my hair, stroking the top of my head with the softest graze I've been touched. The palm of her hand rests on my head as her fingers take strands of hair between them, caressing them, letting them go, repeating the gesture.
        
        We just stay there for a moment. She starts to hum an unknown tune, soothing my soul. It dances its way into my mind, banishing the intrusive thoughts of pain and sorrow. I sigh, slowly.
        
        "Thank you."
        
        She smiles and the sight of it almost makes me forget about the bile in my mouth.
    #Push her hand aside.
        Her features don't flinch, she doesn't take offense over my refusal of her touch. She merely smiles understandably.

"Do you want to talk about it?"

Her eyes ask me to tell what plagues my mind. It's not a scrutinizing gaze, but a concerned one.

*fake_choice
    #Tell her about my siblings.
        *set tinsae_family_truth true
        For some reason, I find myself telling her. 

        "All of my siblings are dead. I saw my big brother, Ciniod, murdered, but my little siblings… I didn't see it. I think they might be slaves right now."

        Tinsae flinches, her brows knitting before her hands hovers over mine. "I'm so sorry." She doesn't offer me any shred of false hope. She doesn't say how maybe they're not slaves. It would only anger me. How would she know? How would anyone know? It's the most probable outcome and I feel like a fool for thinking about it just now.
        
        As if knowing the fact that no words can help with the situation, she merely offers her touch. I gaze at my hands. Stupid, trembling hands. There, above my calloused skin, is Tinsae's delicate hands, waiting for a permission to comfort me.
    #Shake my head. I don't want to talk about it.
        I don't want to voice my fears, so I merely shake my head. I don't know for sure if they are slaves, but for some reason, there's a nagging feeling I might be right about this. I didn't see them killed. I saw brother Ciniod killed, but not the little ones. The Romans wouldn't kill children without a thought. They make better slaves than corpses.
        
        The thought punches me in my gut again and I flinch.
        
        Tinsae doesn't take offense over my silence, but merely nods in understanding. She looks at my trembling hand. I didn't notice it was trembling. Stupid, stupid hand. 
        
        "Can I?" she asks. She moves her hand to hover over mine. There, above my calloused skin, is Tinsae's delicate hands, waiting for a permission to comfort me.

*fake_choice
    #Let her take my hand.
        I give her the slightest of nods, half-expecting she missed it. That is, until she lightly presses her palm over mine. It's a soft touch, as soft as her skin, as if my hands are covered in silk. My hands stop trembling. She raises her gaze away from our hand and gives me a small smile. Her coal-black hair shines under the winter sun.
    #Take her hand.
        Before she can act on her intent, I take a tight hold of her hands to stop mine from shaking. For some reason I wanted to be the one to take initiative. It's a way to make me feel in control in a situation where I have none. She doesn't yank her hands away, as I half expected her to, she merely looks at the intertwined palms before giving me a small smile. Her coal-black hair shines under the winter sun. She squeezes my hands, helping them to steady. Her hands are extremely soft, as if my hands are wrapped in silk.
    #Yank my hand away.
        I quickly yank my hand away from her. I want to be alone right now.
        *goto ch3_tinsae_nope

A couple of men walk past us, their eyes peered into our intertwined hands. Tinsae doesn't seem to mind, but their intrusive gaze makes me yank my hand away.

I need to find them. I need to find any information I can about them.

*label ch3_tinsae_nope
We sit in silence for a good while before Tinsae informs me of a meeting she is going to be having. She needs to leave.

Tinsae fidgets her fingers before turning back to me. "Are you sure you will be fine? I can postpone the meeting."

"I'm sure. Thank you." 

She bids me a quick, uncertain goodbye before hurrying into the crowd.

I let out a small sigh. It's one thing to show your vulnerabilities, it's another to show them to a stranger.

[i]You should see the meeting.[/i]

My eyes widen at the voice. It's back. Again. I peek around me to make sure I'm alone before even thinking about answering. Then I realize it's somewhat unnecessary, since I can speak in my mind without actually speaking. I just have to try and not look like a madman while doing it.

'What do you mean? Why?'

But there's no answer. Why would it want me to go there?

*choice
    #Go there.
        I will have to do something about that. But what? They hold the key to my mind and I can't seem to stop them.

        With a shake of my head I begin walking towards my destination. For some reason I know where to walk, even if the voice didn't tell me any details. It's as if they planted the information in my head.

        Great. That's just great. I'm but a puppet to it.
        *goto ch3_meeting
    #No. I'm going back to the barracks.
        *goto ch3_barracks

*label ch3_barracks
An image of what happened last time when the voice appeared flashes before my eyes: Marcus's bleeding nostrils, his dead-like walk. Even if it seems like it wasn't true, what if that happens now that I'm clearly disobeying the voice?

With a shake of my head I begin walking towards the barracks. It won't happen now. It was a dream.

As my destination becomes clear to me, my feet start to lose their willingness to co-operate. My step is heavy, I almost have to help them with my hands to keep moving. It's as if I'm walking in a swamp and the swamp is getting deeper and deeper.

What is this? Why is this happening?

As beads of sweat start crawling their way across my forehead toward the corner of my mouth, as the taste of salt starts pervading my taste buds, terror starts creeping into my mind. The voice did this. It can alter the state of my body.

Then, a thought pops up into my mind without my will: I know where the meeting is held. Did the voice plant the information in me? Finally I stop my futile attempts to move and sigh. What should I do? This seems dangerous.

*choice
    #Give in and go to the meeting.
        I shake my head. This is too dangerous. The voice clearly wants me to go to the meeting and it can probably kill me for disobeying. I turn around and take a hesitant step, just to see if my feet work now. 
        
        Lo and behold, my legs obey me. Relief surges into me, but it's shadowed by the fact that the voice can do this. Who know what else it can do?
        
        With a shudder shaking my core I start backtracking my way to the meeting, all the while feeling like a puppet to its cause.
        *goto ch3_meeting
    #No. I'm going to the barracks.
        *goto ch3_determined_barracks
    
*label ch3_determined_barracks
*set antivoice true
I grit my teeth and start walking. I barely take a note of a familiar red-haired 
*if height = "short"
    giant of a man 
*if ((height = "average") or (height = "tall")) 
    man 
walking past me, his features confused over my fight against invisible forces.

The voice will [i]not[/i] take my free will. I've already been stripped of everything else. Even if my feet remain akin to two stones I move them with sheer iron will. And they do move. Just a smidgen, but they do.

Try and stop me, you stupid voice! I'm walking away from your schemes!

Then, as if to spite me, the feet fully stop obeying my commands. They take root into the dirt road and stay put. I almost fall flat on my face, but barely manage to keep my balance.

"Hati? What are you doing?" Niall's voice reaches me from behind. He was the man passing me by. It takes a moment or two to realize that I'm looking at a familiar face. A familiar face that looks slightly worried over my mental state as my skin runs wet with sweat even if the day is as cold as any day during late fall.

*fake_choice
    #Help me!
        "Niall!" His given name slips from my lips without any thought. I don't care. I'm stuck. I can't move. I couldn't care less what I should call him, he needs to help me. I don't know how, that's his problem now.
        
        Every shred of confusion and doubt strips from his features and there's only determined worry. "What? What's wrong?"
        
        "I can't move my legs."
        
        "Alright." He takes the information without any questions. "Can I touch your shin?" Then, he adds as if confusion was evident on my features: "I just need to check if your sense of touch is intact." 
        
        I nod, what else can I do? As he receives the approval to touch me, he bends closer to my shins.
            
        *fake_choice
            #He smells nice.
                *set niall_sniff true
                As his hair is unfamiliarly close to my face, it's hard not to inhale the scent of his red, wild hair. It's quite pleasant. Earthy. Like a field of heathers on a sunny late summer.
                
                As his finger grazes my leg, I wake up to the realization that I'm taking a sniff out of him.
                
                *if disciplined < 50
                    Redness creeps onto my cheeks. This is really not the time.
                *if disciplined > 50
                    I quickly regain my composure and merely bite the inside of my cheek.
                He does smell nice.
                
                "Did you feel that?" He asks.
                
                "Um. Yes. I did."
            #Just remain still.
                I wait for him to analyze my state. As his finger grazes my leg, I nod sternly. "I can feel it."
                
        "That's good." He gets back up, rubbing his beard. "You're not paralyzed. What if you tried to walk now?"
        
        And, as if witnessing a miracle in the making, I start to regain the control of my feet. It starts with my toes, it moves higher and higher until the legs are mine again. With my eyes widened I look at Niall. He gives me a relieved smile, the relief must've shown in my own features, as well.
        
        "They work again?"
        
        "Yes, they do." I wiggle my toes just to be sure.
        
        *fake_choice
            #I'm relieved, and so happy that he's here.
                I just keep looking at him with a wide, relieved smile. I was sure I was going to die, or at least paralyze. He was there to help me. A surge of warmth floods over me, melting every muscle in me in its path. I'm alive and I can move again.
                        
                He brushes his beard and clears his throat. It makes me become aware that we're in a busy street and I'm gawking at him.
                        
                I clear my throat, as well.
            #I excuse myself and go back to the barracks.
        "I should go back to the barracks."
        *goto ch3_fire
    #Smile and try to appear as if nothing is wrong.
        I invoke a smile onto my features, even if it feels grating to my facial muscles. This only manages to deepen Niall's frown, but it's too late. I'm committed to my forced joviality.
        
        "I'm fine! I'm just taking a walk!" The answer comes out as two slightly maniacal-sounding shouts. I can't actually be blamed for it: I'm fighting against some unknown entity in my own head. I realize that I've never shouted at him, nor addressed him without titles. "Lord Tribune!" I add for good measure as I try to take another step. It's futile. I can't move.
        *fake_choice
            #I'm starting to panic.
                I can't move my legs! I'm going to be stuck here forever. I will turn into a mummified stone and become a tourist attraction for this measly town. People will draw graffiti on me and decorate my head with a wreath during holiday season.
                
                The mental image is so absurd that I would laugh if a major part of me didn't actually believe it within the realm of possibility.
                
                "Hey!" A shout draws me back to realm of reality. Niall's voice is closer this time, he's taken steps towards me, his hands raised in a calming gesture. "It's alright. Just take deep breaths."
                
                I do as I'm told and start inhaling heaps of air. I'm going to fill those lungs like they've never been filled before.
                
                "No, listen to me. Take one deep breath and hold it."
                
                I bite my lip and try to do as I'm told. 
                
                "Just like that. Then hold it for a couple of moments."
                
                With my eyes closed I obey his voice. It has a soothing tone in it. It almost makes me believe that everything will be alright.
                
                "Breathe out. Hold it. You're doing great."
                
                That's how we stand in the middle of busy street, him telling me how to breathe and me obeying him. So many people pass us by but I ignore it. It's easy to do when he speaks. It's something to anchor my mind onto. And, as if witnessing a miracle in the making, I start to regain the control of my feet. It starts with my toes, it moves higher and higher until the legs are mine again. With my eyes widened I look at Niall.
                
                "It worked. I can feel my legs again."
                
                "That's a relief!"
                
                *fake_choice
                    #I'm relieved, and so happy that he's here.
                        I just keep looking at him with a wide, relieved smile. I was sure I was going to die, or at least paralyze. He was there to help me. A surge of warmth floods over me, melting every muscle in me in its path. I'm alive and I can move again.
                        
                        He brushes his beard and clears his throat. It makes me become aware that we're in a busy street and I'm gawking at him.
                        
                        I clear my throat, as well.
                    #I excuse myself and go back to the barracks.
                "I should go back to the barracks."
                *goto ch3_fire
            #This is fine. I'm fine.
                I take a deep breath to stabilize my racing heartbeat. Everything is fine. I'm sure this isn't permanent, I'm not just going to be stuck here forever. The voice is doing this to me but it doesn't seem to be after my life. It needs me for something. It wouldn't leave me here to rot.
                
                So I merely close my eyes, even if a part of me feels Niall's inquisitive gaze on me. I take a deep breath, and another.
                
                And, as if witnessing a miracle in the making, I start to regain the control of my feet. It starts with my toes, it moves higher and higher until the legs are mine again. With my eyes widened I look at Niall. He, of course, has absolutely no idea why I'm giving him a relieved smile, but he smiles back.
                
                "You're feeling better now?"
                
                "Yes. Thank you."
                
                "I'm not sure if I did anything but I'm happy to hear that." 
                
                *fake_choice
                    #I'm relieved, and so happy that he's here.
                        I just keep looking at him with a wide, relieved smile. I was sure I was going to die, or at least paralyze. He was there to help me with his presence. A surge of warmth floods over me, melting every muscle in me in its path. I'm alive and I can move again.
                        
                        He brushes his beard and clears his throat. It makes me become aware that we're in a busy street and I'm gawking at him.
                        
                        I clear my throat, as well.
                    #I excuse myself and go back to the barracks.
                "I should go back to the barracks."
                *goto ch3_fire
    #Just try to walk to the barracks and leave him.
        "I'm going to the barracks!" I shout at him, at myself, at the voice. I declare it to everyone, perhaps it would make it more true.
        
        I grit my teeth and make the damn legs move. They [i]will[/i] move. I'm not going to make anyone tell me what to do with my own damn legs.
        
        And, slowly, as if melting from their frozen state, I start to regain the control of my feet. It starts with my toes, it moves higher and higher until the legs are mine again.
        
        With my eyes widened I stare at the legs for a couple of moments before realizing that I'm in the busy street and Niall is probably gawking at me like a fool. I hastily take my leave, like nothing was wrong. 
        *goto ch3_fire

*label ch3_meeting
*page_break
The meeting is in the temple of Isis? I have seen the temple in passing, but I've never been there. Just as I'm starting to think as to how would I know how to sneak into a foreign temple that I know nothing about, a route to the meeting pops into my mind. 

The voice seems to have left me with more instructions. How… nice of it?

Or terrifying, more like. Last time the voice appeared in this fashion Marcus was bleeding his insides out. Even if it was a dream…

I shake my head.

The temple complex is larger than I thought. There are multiple buildings, different altars, and I shouldn't have no idea which one is the right one.

But I do. An image of a window I've never seen in real life lingers on my mind before I see it with my own eyes. That's it. I quickly slip inside with my heart racing so loudly in my chest that I fear it might alert the others.

This is most likely something I shouldn't be seen doing. Would it be enough to have me killed? Perhaps. What isn't, nowadays?

Scents of incenses attack my nostrils as I enter the building. This seems to be a housing of the priests, judging by the more homely furnishing than I expect to find in a temple. There's a chest filled with robes. A part of me fears I can't get the trunk open once I'm in there but that should hide me well enough.

It will do.

Then, as if in cue, I hear the approaching of two women I apparently came here to spy on. I jump into the chest. 

It's small. 
*if height = "short"
    Fortunately, I'm small, too. I fit in without much effort and slip the lid closed. I have time to steady my breathing before the voices reach the room I'm in.
*if height = "average"
    It takes some adjusting but I can fit in here. I slip the lid closed just in time.
*if height = "tall"
    Well, shit. It's too small. But as the voices come closer, I realize there is no time to come up with a better plan. 
    
    Into the damned trunk I go. After a hurried shoving of my too long limbs I finally fit into the thing. Just as the door opens, I close the lid of the chest, praying to the Twins that they didn't notice. Then I realize that I should also pray that they don't hear my labored breaths.
    
    This was a bad idea.

*page_break
"Why are you asking me these questions, Cam?" Tinsae's voice. Worry coats her words, her tone is anxious. I can almost see her fidgeting. "I can get the information for you, but I have to know what this is about."

Camilla's voice is defensive and colder than how she usually talks to her friend: "You'd just try to stop me."

Tinsae sighs. There's a sound of someone slumping themselves on a chair. Tinsae, most likely. "That's even more of a reason to tell me."

A band of rambling priests walk past the building, most likely the same window I used to slip in. A series of prayers fill the room just in the worst possible time. I can't hear what they are saying.

"Are you out of your mind?" Tinsae gasps.

Damn. I missed something important.

"I know what I'm doing. Just get the information and everything will be fine."

"Fine? I…" Tinsae sighs, again. Then, after a long silence: "Fine. But only because it will ensure your safety."

"Thank you. I couldn't do this without you."

"That doesn't make me feel any better." She sounds disappointed. "Worse, if anything."

"You know why I'm doing this."

"I don't want to talk about this. The walls have ears."

Trunks, more like.

"I've payed for those walls, they wouldn't dare."

Tinsae's voice is hesitant. "Still… even talking about this is cause for an execution."

"I won't let anything happen to you."

There's a deep, forlorn sigh. "Let's just leave."

That was too close. As the voices of the two women finally leave the room, I can exhale. 

Now, all I need to do is get out of here.

*if build = "lithe"
    However, try as I might, the lid won't open. It's too heavy. The air is becoming heavier and hotter as I strive to even move the damned thing. How did I even managed to open it in the first place?
    
    Panic fills me in a flash of lightning. I can't shout for help! 
    
    Shit shit shit. The priests will find me.
    
    Then, the lids opens. Fresh air and a dim light fills the trunk as I squint at the person who's standing above me.
    
    "Quinn?"
    *page_break
    "Got stuck there?"
    
    "Thank the Twins," I mutter as I breath the fresh air. "What are you doing here?"
    
    "I followed you." Quinn looks at me with a small grin.
    
    I quickly get up from the gods-forsaken chest, sparing no glance at it. "Why?"
    
    "You looked like you were sneaking about. Colored me curious." $!{q_he} shrugs. "Then I heard you panicking about in the chest." $!{q_he} peeks at the heavy-built trunk. "Why did you shove yourself in there?"
*if build = "average"
    The lid is incredibly heavy. It's a wonder how I managed to open it in the first place. The air is becoming heavier and hotter as I strive to open the damned thing. 
    
    Then, it moves.
    
    Relief fills me. 
    
    However, it's not opened yet. I can get out of here, I just need to push a little harder, I—
    
    The lid opens. But not by my hand.
    
    I squint at the person above me.
    
    "Quinn?"
    *page_break
    "Got stuck there?"
    
    "I was just going to get out of there myself," I mutter as I breath the fresh air. "What are you doing here?"
    
    "I followed you." Quinn looks at me with a small grin.
    
    I quickly get up from the gods-forsaken chest, sparing no glance at it. "Why?"
    
    "You looked like you were sneaking about. Colored me curious." $!{q_he} shrugs. "Then I heard you panicking about in the chest."
    
    "I wasn't—"
    
    $!{q_he} ignores me and peeks at the heavy-built trunk. "Why did you shove yourself in there?"
*if build = "heavy"
    The lid is heavy but it's nothing I can't handle.
    
    Just as I'm dusting myself off of the priest robe particles, I notice a peculiar sight leaning against the doorframe.
    
    Quinn.
    *page_break
    "Got yourself out of there without my help?"
    
    "Of course. Nothing I can't handle." 
    
    $!{q_he} gives me a pout before grinning.
    
    I shake my head. "What are you doing here?"
    
    "I followed you." $!{q_he} shrugs.
    
    I didn't see ${q_him} at all. $!{q_he}'s sneaky. "Why?"
    
    "You looked like you were sneaking about. Colored me curious." $!{q_he} peeks at the heavy-built trunk. "Why did you shove yourself in there?"
    
"I just needed to hear what Camilla and Tinsae were talking about."
    
"Oh? You [i]were[/i] sneaking about! Tell me all the juicy details."

"I didn't hear much. Just something about information-gathering and such."

"That's all?" $!{q_he} looks disappointed.

"Unfortunately." I shake my head. This seemed pointless. I wonder why the voice deemed this so important. "Let's leave before anyone spots us."
*goto ch3_fire

*label ch3_fire
*page_break
[i][b]Later that night[/b][/i]

Still recovering from today's trials, I find myself attracted by the warmth and light emanating from the campfire next to our barracks. With a sigh I sit down, knowing fully well that I won't be alone for long. The night is cold and the fire attracts soldiers like moths; it's happened to a many more fires around the camp. And, as predicted, Kegan is the first one to appear, closely followed by Floyd. Soon I'm surrounded by our whole contubernium. The tips of my fingers slowly melt from their frozen state. 

"You'll be a sentry for tonight?" A voice beside me asks. Quinn peers at me before taking a seat. Quinn is already a familiar figure in our group, ${q_he} helps with the armor and no one seems to particularly mind ${q_his} presence. $!{q_he} comes and goes, as is the case tonight, too.

I nod.

Floyd takes a loaf of bread from his rucksack. "Anyone hungry? Hati, please come and take one." He smiles, as he usually does. The smile is warm, despite the freezing air. "You, too, Quinn." 

Before I can even answer, Brick stomps to Floyd with an erected hand demanding his share. He's closely followed by laughing Pec, who tackles the big man from behind, causing both of them to collapse on the ground. Brick swears in both Briton and Latin, cursing Pec to the depths of the underworld. 

Pec shouts:
*if ((brick_tackler) or (brick_hitter))
    "Oy, Hati! Help me with the big one! You showed us all how it's done!"
    
    I shake my head, not interested in a wrestling match. Brick takes a chokehold of the shouting Pec.
*if brick_friend
    "Oy, Hati! Help me with the big one!"
    
    Brick throws a quick, questioning glance at me, and I shake my head. He nods with a slight smile before jumping at Pec.
    
    "You traitor! Have you allied yourself with the big one?" He shouts before Brick has him in a chokehold.

An unintended smile sneaks its way to my lips. Watching the men sends my mind wandering to my father's warriors. They were a rowdy bunch, even louder than this lot. They adopted me as their own, giving me a label of a warrior of honor. Ever since I was little, they showed me how to hold a sword, how to hunt, to roam the wilds. Mother seldom approved of my time away from my studies, but only expressed it through scowls when I waved her goodbye and left the grove.

I even tossed cabers with the warriors.

"Remember the caber-tossings with the warriors?" Quinn asks as if reading my mind.  

*if ((build = "lithe") or (build = "average"))
    "Although in your case…" $!{q_he} wears a slight smirk. I sigh, knowing exactly what ${q_he} is going to say. I did not throw them well.
        
    "They are heavy," I say, even if I know better than to start defending my pathetic attempts. I couldn't even get the damned logs off the ground. The men got a good laugh out of me and I swear I saw Quinn there too with ${q_his} hands covering ${q_his} snickering mouth before coming to check if I strained any muscles in the process.
    
*if build = "heavy"
    "You were good," ${q_he} says with an appreciating nod. 
    
    "I suppose I was," I say. I know I was. There were only a few who threw the logs as far as I did, let alone get them off the ground. Every time I searched for father's gaze after a successful throw, his smile was wider than I think I've ever seen.

    Quinn scoffs. "You suppose? Weren't you a caber-tosser of honor or something?"
    
"Caber-tossing? Isn't that practiced in Caledonia?" Floyd's voice halts the discussion. 

Shit.

His gaze still holds the remnants of the warmth they held just a while ago, but it's muddied with puzzlement. I need to think something, quick.

*fake_choice
    #"It's a thing in the Northern Britannia, too."
        Quinn confirms the lie with a firm nod, ${q_his} chin almost touching ${q_his} chest in a violent move. "Yes!"
        
        "Oh." Floyd squints his eyes, but finally nods. "That explains. I come from South."
        
        I sigh in relief. That was too close.
    #"Did you hear cabers? I meant neighbors."
        Quinn's eyes widen even further at my excuse. $!{q_his} frame starts to shake, as if ${q_he}'s holding in a fit of laughter.
        
        Floyd squints his eyes, clearly processing my words. "You… tossed neighbors?"
        
        "Yes. A small village. Weird habits." I just want to smack myself for not coming up with a better lie. Quinn is not helping.
        
        "I'll say." He ponders for a moment, opens his mouth to ask, but finally decides against it. It's as if I hear him say 'northerners' with a slight smile, but I could be wrong.
    #Just stare at him.
        I don't come up with a lie, so I'll just settle for a dumbfounded look. Floyd raises his brow at me, waiting for me to say anything.
        
        Quinn jumps in: "It's a thing in Northern Britannia, too."
        
        I nod quickly to confirm the lie. 
        
        "Oh. Well that explains. I come from the South."
        
        I sigh in relief. That was too close.

"Well, never mind that. Here's a loaf for the both of you before Brick eats everything." There are little greens of different herbs giving the loaf an extra touch of care.

A strong scent of 
*if herbalist
    yarrow 
*if not(herbalist)
    some sort of a herb
wakes my appetite.
    
"Thank you."

"No problem." He smiles and leaves to distribute the rest of the bread to Mack and Mak, eagerly waiting for their turn. But not before shouting at the wrestling pair on the ground: "Oi! Stop that, you're behaving like children."

Floyd returns to me, sitting next to me. The atmosphere is relaxed, almost pleasant.

*choice
    #Talk to the men.
        *goto ch3_squad_bonding 
    #Ignore them.
        *goto ch3_quinn
    
*label ch3_squad_bonding
Floyd shakes his head as he's watching the bickering men, now nibbling on a piece of bread. "I miss my children."

I shift my gaze to him. Grief over children left behind embellishes his features. There's beauty in it despite its sorrow; it's a face of a man who loves his offspring. "How many do you have?"

"I think the count was 7, last time I checked. I really hope they haven't multiplied when I'm away!" He gives me a goofy smile while he's hoping his wife hasn't cheated on him. It's difficult to know if he's being serious.

I nod. "That's a handful." There were only 4 of us, yet mother still looked like her hair might fall off.

"Children are prone to trying to kill themselves. They eat what they're not supposed to, they try to drown themselves in lakes and rivers… It's a job in itself to keep them alive."

That would explain father's grayish hair when he was only 30. Floyd falls silent again and keeps looking at the fire with a wistful smile. If I remember correctly, he's one of those who got conscripted unwillingly. 

*fake_choice
    #"I'm sorry you had to leave them behind."
        *set group_friendship +1
        "Thank you. My wife is a strong-willed woman and our extended family is large. She can manage. I just wish I'd see the little ones climb their first trees. Or catch their first butterflies."
    #"I used to eat rabbit poop when I was little."
        *set group_friendship +1
        He breathes a quick puff of air out of his nostrils before bursting into a fit of laughter. "You were one of those children, I should have known!"
        
        Pec grimaces. "You ate poop? Why? How? No. Don't tell that part."
        
        I shrug. "I thought it was good." Father chased me while my cheeks were brown with rabbit poop. He never let me forget that.
        
        That is quite disgusting and I'm happy that I didn't catch anything lethal.
    #Remain silent.
        
Quinn scoffs: "Romans just keep spreading grief everywhere they go."
        
Floyd gazes at ${q_him} with an understanding smile. It's as if he's looking at a brooding child. "Life is filled with grief and suffering, my ${q_boy}. The only thing that counts is how we choose to react to it all." 

The words linger between us. Quinn frowns, begins to open ${q_his} mouth but decides against it, clearly not interested in starting an argument with the older man. 

Floyd continues: "At least I will earn the citizenship. And I can send money for my family."

Pec joins the conversation with a wistful shrug: "I don't have anyone waiting for me at home. Might as well be here."

"What about your parents?" I ask.

"Dead and buried."

I don't know why I asked, that was the most probable answer. He, however, doesn't look too bothered by it. Neither by my question, nor by the fact that they are dead. He merely gives me a smirk. "I'm here for the adventure. Right, Kegan?" 

Kegan nods eagerly. "Yeah. But I think that you guys are the reason I like it here." His words lose their strength at the end of his sentence, one has to take an educated guess as to what the rest of the words were. Kegan's face is flushed as he hides behind the neckline of his tunic.

*fake_choice
    #Give him a pat on the back.
        *set group_friendship +1
        It happens almost without thought, the reassuring gesture. I touch his shoulder blade lightly and give him a quick squeeze. His face flushes even deeper red, but still he turns to give me a wide smile. He nods, clearly to thank me. I nod back and turn my gaze back to the fire.
    #Remain seated and silent.

*if brick_friend
    Brick shifts uncomfortably when the conversation topic moves to families left behind. He had to leave his mother.
    
*if not(brick_friend)
    Brick looks like he's swallowed a spruce sprout. I wonder what's wrong?
    
    *fake_choice
        #Ask what's wrong.
            *set group_friendship +1
            "Brick? What's wrong?"
            
            He gives me a stink eye so fast I fear his eyes might bulge out of his sockets. 
            
            He doesn't want to let me know.
        #I'd rather not.

*label ch3_quinn
*page_break
The crackling of the burning logs fills the silence.

Kegan's tiny voice interrupts my non-thoughts: "What about you, Hati? Do you miss your family?" 

I barely take a note of Quinn's stiffened posture as my thoughts race to search for an answer for the boy's question. I fixate my gaze to the flames, as if the answer would be there.

Do I miss them?

My brother. My sister. The faces of the twins appear before me without my will. Her messy self-cut hair, her eyes filled with mischief and iron will. His soft gaze and a hesitant smile. My big brother with his mimicked posture of our father, his golden blond hair and a winning smile.

Their faces are accompanied by father. His squinted eyes is a tell tale of a smile under his formidable beard.

Then my… My mother.

Every breath I inhale burns my lungs. I try not to look at my hands; I know they are trembling. Again. Why is this happening now? I know they are dead. I [i]wish[/i] they were dead and not slaves to the Romans. I can't do anything, I—

No.

"No!" I blurt out and stand up. Kegan looks at me with his eyes widened.

*fake_choice
    #I need to leave the situation so I won't say anything I will regret.
        *set coping_hermit true
        With a deep frown I finally glare at my trembling hands. The treacherous, trembling hands, showing everyone my weaknesses, my open, festering wounds. But before I can comply to the need of my throbbing anger, to lash out and rage, my feet lead me away from the stuffy air. I need air. 
        
        Cold, clear air.
        
        The promise of coming winter pinches my cheeks, relieving my body and mind of any thoughts. I take a breath, and another, replacing the previous shallow gasps of air with ones that are deeper, better.
        
        Only a few distant steps intrude the silence. Quinn.
        
        I open my eyes slowly and look at the sky. The stars. The constellations are differently positioned here. Just another reminder that I'm not at home.
        
        But they're the same. They just look different. I close my eyes again with another breath of cold air.
        
        They're the same.
    #Anger fills me.
        *set coping_anger true
        With a deep frown I finally glare at my trembling hands. The treacherous, trembling hands, showing everyone my weaknesses, my open, festering wounds. I yank my eyes to the boy in front of me. The one who triggered all of this.
        
        "I'm sorry." I can barely hear him, his words so small and fragile. 
        
        I curl my hands into fists, my nails penetrating the skin of my palms. He's sorry. My teeth chew the skin of my cheeks, and I will myself not to do anything that would endanger my position here. It's the only thing keeping me from doing something I'd regret.
        
        He's sorry. He didn't know.
        
        "It's alright." A hand takes a hold of my shoulder.
        
        With the speed of a wounded animal I turn to the intruder holding me without my consent, and see Quinn standing there, the new target for my throbbing anger.
        
        "Hati, it's alright," ${q_he} says, as if ${q_he} would know anything.
        
        I force my neck muscles to comply, to nod.
        
        "I think we should get a bit of fresh air, don't you think?"
        
        I nod again. Quinn's cold skin against my palm leads me away from the heat, from Kegan's distressed eyes.
    #I'm alone. Everyone is dead and I'm alone. 
        *set coping_company true
        Overwhelming loneliness washes over me, expanding within my rib cage with every burning breath I take.
        
        I can't make this on my own. Why did I thought I would? I'm alone, surrounded by strangers. Alone in the world, everyone either dead or my enemy. They're all dead. Everyone I knew and loved, everyone of them dead in the ground as the maggots feast on their flesh.
        
        Rising panic starts to take a hold of my chest, pressuring it with its might.
        
        Then, someone takes a hold of my shoulder.
        
        "It's alright." Quinn hushes, $!{q_his} whisper soothing my mind. At least a fraction of it. It smooths the edges of the panic, numbing it just a little. "I think we should get a bit of fresh air, don't you think?"
        
        I nod, and ${q_he} leads me away from the heat, and Kegan's distressed eyes.

*page_break
Quinn sits down on a large stone residing next to the road before beckoning me to sit next to ${q_him}. 

*fake_choice
    #Remain standing.
        *set ch3_stand true
        Still rattled by the episode, I remain standing. It's better that way. It makes me feel more in control of myself. Quinn doesn't say anything about my decision, ${q_he} merely shifts ${q_his} gaze to the stars. And, finally, I do too.
        
        The sight manages to soothe my mind.
        
        Finally, Quinn breaks the silence:
    #Sit next to ${q_him}. 
        *set quinn_friendship +1
        The stone is cold to the touch but big enough for the two of us. $!{q_he} doesn't say anything, ${q_his} eyes peered at the sky and its countless stars. I turn my gaze to the stars, as well. The sight soothes my mind. Finally, Quinn breaks the silence:

"Do you remember what you said? About the dead and the stars?"

I nod.
*if ch3_dead_yup
    "I said that they're watching us." 
    
    Which one of them is my father? It must be the biggest and the brightest. Big brother must reside alongside him, smaller but no less bright.
    
    $!{q_he} nods with a small, subdued smile. "It helps, doesn't it? To think that they're there."
    
    It does, even if just a little. Is every one of the stars someone's loved one? There must be millions of them. So much grief and love decorates the night sky.
*if ch3_dead_dunno
    "I said that I'm not sure."
    
    $!{q_he} nods with a small, subdued smile. "I think they are there." $!{q_he} turns ${q_his} gaze back to the stars. "No. I'm [i]sure[/i] they are there."
    
    Maybe they really are there. Do they feel pain, or sadness? Can they see me? Is every one of the stars someone's loved one? There must be millions of them. So much grief and love decorates the night sky.
*if ch3_dead_nope
    "I said that they're not there."
    
    There's a light smirk on ${q_his} features as ${q_he} turns to me. It's not mocking, but something else. "Why do you think that? Where do you think they are, then?"
    
    It would be easier to believe that they're there, watching me.
    
"I think they can see you," Quinn says. "And I think that the dead feel nothing but love for those they left behind." $!{q_his} words are wistful. The stars are so bright this time of the year. I could get lost in them, searching for the souls of those I love.
    
*if not(ch3_stand)
    Something grazes the skin of my hand ever so slightly. Quinn's hand hovers over mine, waiting for a permission to take a hold of my hand.
    
    *fake_choice
        #Let ${q_him} take my hand.
            *set ch3_hand_quinn true
            I nod and ${q_he} wastes no time grab my hand. The gesture is quick, almost alarming in its hastiness, but once my hand rests in ${q_his}, all of the tension taking a hold of my body melts away. $!{q_his} hand is cold, as I suspect is mine. 
        
            $!{q_his} freezing skin against my own we sit on the stone, gazing at the stars; two souls who have lost everything.
        #Grab ${q_his} hand.
            *set ch3_hand_quinn true
            I don't wait for ${q_his} action but take ${q_his} hand instead. $!{q_he} throws me a surprised glance before giving me a wide, satisfied smile. $!{q_he} squeezes my hand once, almost too tightly for my freezing hand, but the touch manages to melt the tension away from my shoulders. Then, ${q_he} turns ${q_his} gaze back to the sky.
        
            $!{q_his} freezing skin against my own we sit on the stone, gazing at the stars; two souls who have lost everything.
        #Yank my hand away.
            No words are exchanged, no hurt glances. We just keep gazing at the stars; two souls who have lost everything.

*if ch3_stand
    Something grazes the skin of my hand ever so slightly. I look down to see Quinn's hand hovering next to mine, waiting for a permission to take a hold of my hand.
    
    *fake_choice
        #Let ${q_him} take my hand.
            *set ch3_hand_quinn true
            I nod and ${q_he} wastes no time grab it. The gesture is quick, almost alarming in its hastiness, but once my hand rests in ${q_his}, all of the tension taking a hold of my body melts away. $!{q_his} hand is cold, as I suspect is mine. 
        
            $!{q_his} freezing skin against my own we sit on the stone, gazing at the stars; two souls who have lost everything.
        #Grab ${q_his} hand.
            *set ch3_hand_quinn true
            I don't wait for ${q_his} action but take ${q_his} hand instead. $!{q_he} throws me a surprised glance before giving me a wide, satisfied smile. $!{q_he} squeezes my hand once, almost too tightly for my freezing hand, but the touch manages to melt the tension away from my shoulders. Then, ${q_he} turns ${q_his} gaze back to the sky.
        
            $!{q_his} freezing skin against my own we sit on the stone, gazing at the stars; two souls who have lost everything.
        #Yank my hand away.
            No words are exchanged, no hurt glances. We just keep gazing at the stars; two souls who have lost everything.
        
Then, someone interrupts the peace: "Am I interrupting?"

*if ch3_hand_quinn
    I quickly yank my hand away from ${q_his} grasp. 
    
    Pec. His gaze lingers where the hands were held just a heartbeat ago.
    
    With his brows slightly raised, he gives me a small grin. "I suppose I am!" As if that's a good thing.
    
    "What do you want?" 

*if not(ch3_hand_quinn)
    Pec. He gives me a lazy grin when I look at him. "What do you want?"
    
"Guard duty awaits," he says and struts off into the darkness.

*page_break 
Quinn bids me a quick farewell before leaving me for my duty. I climb into one of the watch towers looking straight at the river that separates the Romans from Germania. The forest is beautiful, even if I don't see much in this darkness. The stars reveal the silhouettes of the trees, standing like giant guardsmen protecting the unconquered land behind them. Even the trees look wild and uncivilized compared to the ones this side of the river. As they should. The trees surrounding the fort are young and tamed, used for fuel and fences.

The water moves lazily tonight; watching it makes the lids of my eyes droop. I quickly open them wide and give myself a good pinch. 

The Romans are eager to kill any soldiers found napping on their guard duty.

Wouldn't want that to happen.

Something catches my eye in the forest over the river, alerting my senses, waking my mind immediately. I squint at the spot where the flash of something — or someone — ran past. It's too dark to see, but I could swear I saw something.

Then, a voice cuts through the freezing night. I turn around to see…
*choice
    #Niall.
        *goto_scene chapter3_sentry ch3_sentry_n
    #Marcus.
        *goto_scene chapter3_sentry ch3_sentry_m
    #Camilla.
        *goto_scene chapter3_sentry ch3_sentry_c
    #Tinsae.
        *goto_scene chapter3_sentry ch3_sentry_t

*label ch3_next_day
*page_break
[b]Next day, at the courtyard[/b]

With my mind blank I stare at the raging Optio. Kegan's posture wasn't to his liking and he's yelling at the boy. Pulsating veins peek prominently under the horse-hair helmet he so proudly wears even during regular training.

A tiring scene, all too familiar.

*if ((kegan_friendship > 50) or (ruthless < 50))
    I wish I could help the boy. All I can do is give him a reassuring nod or a glance after he's had his yelling quota for the day. The Optio hazes the only child in the troops. A clear sign of a weak and pitiful man.

[i]And he calls us barbarians.[/i] The voice again.

My eyes widen. It's back. With heightened senses I try to locate it within me, only to find it an impossible task. This is starting to get old and tiring.

'Who are you?!' I whisper-yell at the voice, this time keeping my actual mouth shut. If I keep acting like a crazy-person, they will have my head.

The voice doesn't answer.

Of course it doesn't. It comes to taunt me and leaves.

"Are you fucking deaf, soldier?" Someone yells and I focus my gaze to the red face in front of me. The Optio.

"No, sir?"

"What did I just say?"

I have absolutely no recollection of him talking, and I wouldn't welcome another beating at a time like this. 

Not that there's ever a good time to get beaten.

With my mind in shambles, I answer: "Something about…"

*fake_choice
    #"...listening to you, sir?"
        *set disciplined +1
        He squints his eyes in clear annoyance. It seems I was right, he's way too predictable a person to trap me with his games. He has no reason to beat me now. Will he do it anyway? Has he ever needed that much of a reason?
    #"...me being a maggot, sir?"
        *set disciplined -2
        He frowns. The answer seems to have been technically right, but not what he looked for, obviously. Will he beat me for it? Maybe a little beating would clear my mind. I almost laugh at the thought.
        
        This is just too much.
    #"...you being a dick? Sir."
        *set disciplined -5
        *set zoilus_dick true
        Military decorum is far from my fogged mind right now. Maybe a little beating would clear it. I almost laugh at the thought. 
        
        This is just too much.
        
        Zoilus's face distorts into one of pure rage as couple of gasps surrounding us reach my disinterested ears. 
        
I pay only half a mind to the raging Optio as I try to get the voice to speak up again. I'm not sure if I want it to speak or not, but it will speak again, sooner or later. Better for it to be on my terms.

'Show yourself!'

Just as the words 'show yourself' find themselves freed in my mind, it's as if freezing water floods through my whole body, numbing everything in its path. The last unfortunate sight before darkness devours me is the Optio's red, angry, and quite confused face.

*page_break
With my head against something cold there's only darkness. The substance beneath me should be stone but for some reason it doesn't feel like one. It's just… cold. 

I think I'm awake. I'm almost certain I am. 

Also, there's a presence next to me.

I open my eyes to the black sky peering at me. Is it night already? Have I lied here for hours?

I shift my gaze to the stranger beside me. $!{q_his} hair is striking white, almost ethereal in nature. It shines brightly along with ${q_his} features. It's not a face I recognize but something about ${q_his} presence makes my muscles… relax. It happens without my will, as my mind tries to protest. This is not the place to get comfortable, it tries to say. I easily silence any objections and close my eyes.

The months' worth of pain, fear, loss, and hate melts away from my shoulders: my neck is freed from its constraints, my stomach light and knotless.

How long has it been since I could relax in this manner? 

Too long.

The scent of lilacs creep into my mind, embracing my every thought. It could be over-powering to someone; not to me. The grove was filled with lilacs. Every spring it bloomed with white and lilac, the scent making my head pleasantly dizzy. When the summer came and the lilacs withered away, my mood dropped for a few days. But I always knew they would come back.

The stranger moves ${q_his} hand closer to me, almost touching my forehead. The movement makes me aware ${q_his} presence again, yanking my thoughts away from the grove. I try to focus my gaze to ${q_him}, but ${q_he} remains foggy. There's a smile on ${q_his} face, that much I can see. 

$!{q_his} face starts to become more clear. Bit by bit I start making sense of ${q_his} features and the sight makes me even more confused. 

It's…

Quinn?

*page_break
As the realization of ${q_his} identity hits me, the shape of ${q_his} face becomes more clear, the color of ${q_his} hair ${q_his} own.

"Quinn!"

$!{q_he} moves away, as if scared of my reaction. "Whoah! Did you expect a demon or something? Of course it'd be me." $!{q_he} grins as if we're meeting on a street, as if ${q_he} just told me something hilarious and waits for me to laugh with ${q_him}.

"Yes, we are in your head," ${q_he} says as if it would explain anything and everything.

*fake_choice
    #Ask calmly what's going on.
        *set disciplined +2
        Even if my head hurts — there's someone prancing about in there, after all — I bite my lip and keep myself calm and collected. With a deep breath I will my voice to be steady. It doesn't pay to panic in difficult situations, that's what my father used to say.
        
        "That's a really impressive thing about you, you know," Quinn says. "You meet me in your head and you can be calm about it. I fully realize I'm acting like this is all normal and stuff, but you know… it's not."
        
        "Yes, thank you. I'm aware of that." I stand up, taking in the surrounding. It's pitch-black, only the area we're in is lit with white light. The sight is so foreign that my feet try to collapse back to the ground. It's one thing to witness such things in dreams, but I seem to be awake right now. Quinn stands up and tries to offer me ${q_his} hand. 
        
        I shake my head. I'm even half ready to give ${q_him} a benefit of a doubt and let ${q_him} help me. $!{q_he}'s infiltrating my mind. "How is this possible? What are you doing here?"
        
        "I knew that would be the first question, yes. Or multiple questions. And I will explain everything with the best of my abilities."
    #"How is that a matter of 'of course'!" I'm agitated, how could I not be? How is this even possible?
        "Now, now, there is no need to shout." 
        
        The request does nothing to ease my mind, in fact, it only manages to fuel my confused anger. Quinn seems to take a note of this and raises ${q_his} hands quickly in the air. 
        
        "No need to get worked up! I understand this is somewhat weird." 
        
        "Somewhat weird?!"
        
        "Well, yes. A little more than that. But don't worry! I will explain everything."
    #Nod. Just keep aggressively nodding. As if it would make me understand and accept the situation.
        So I remain seated, just nodding as I notice that our surroundings is a pitch-black void of nothingness save for the space Quinn and I are in. There's a white light illuminating our area, but there's nothing surrounding us.
        
        The sight takes a grip of my stomach and I quickly turn my gaze away. I nod as I realize that maybe Quinn isn't Quinn at all, most likely ${q_he}'s just the product of my imagination. Or maybe ${q_he} [i]is[/i] a demon. I would be a fool to take a demon's word for that they're not a demon. 
        
        "We can sit, sure," 'Quinn' says and shifts ${q_his} position next to me. The movement makes me fully aware how close ${q_he} is. The realization makes me stand up with haste.
        
        'Quinn' follows my example. "I'm not a demon."
        
        "You keep saying that."
        
        "Because it's true."
        
        "Why would a demon tell me that they're a demon?"
        
        "Well, true." $!{q_he} rubs the back of ${q_his} neck. "Please, just let me explain everything. You can decide if you believe me or not."

*page_break
So I wait with my arms crossed.

$!{q_he} shifts uncomfortably. "Do you want a—"

"If you ask me if I want a cookie so help me the Twins I will…" I shake my head. "Just tell me what's going on."

$!{q_he} sighs and bites ${q_his} lip. "There is no good way to tell you this and I know this sounds ridiculous…"

"Tell me already."

"When you left, I sort of… got in contact with the Twins." $!{q_he} winces and looks at me, as if realizing how stupid this all sounds.

"The… Twins?"

"Yes. [i]The[/i] Twins."

"You got in contact with the Twins."

Quinn nods.

$!{q_he} just… got in contact with my gods. They have never spoken to me, but they spoke to Quinn, of all people.

"They just appeared to you?"

"Not exactly. I had to do a lot of stuff to get their attention. You know how gods are."

*fake_choice
    #"Do I? I wasn't even sure they were real!"
        $!{q_his} brows shoot to ${q_his} forehead. "You're their druid yet you doubted their existence?" There's something beneath ${q_his} voice, something hurt and… perhaps sneer? If there was something akin to that, it's quickly gone, replaced by an understanding smile. Is it just fake? 
        
        "It's difficult to believe in something that doesn't show themselves to you. Yes." The smile on ${q_his} face is strained.
        
        "You seem like it bothers you?"
        
        "What? No. Of course not. But isn't it great that they are real?"
        
        "How did you come up with contacting them?"
        
        "It was my last resort. It was the only thing I could think what would help you. I would've been useless to you without their blessing." $!{q_his} voice is seeped with self-pity, bordering on self-hatred. $!{q_he} shakes ${q_his} head and gives me a quick, easy smile. "Now I can really help you."
        
        I slowly shake my head. If everything mother told me about the Twins is true, the fact that they're seemingly real and Quinn made a pact with them is concerning.
        
        The gods can be greedy and unpredictable.
        *if sex = "male"
            I have the scar tattoo to remind me. The Twins wanted their druids to suffer through pain.
        
        *if sex = "female"
            The scar tattoo of the Twins on my chest itches as I think of it. It never ceases to remind me of the time I screamed my lungs out as mother cut my skin. The cuts were deep. That's what the Twins demanded, she said.
            
            The Twins wanted their druids to suffer through pain.
            
        However, it feels ludicrous to believe everything ${q_he} says. Despite the fact that we're talking in my head, which makes the situation somewhat more believable. "Then what?"
    #I nod. I do know them.
        *set believer true
        I know too well. The gods are greedy, bordering on rapacious.
        *if sex = "male"
            I have the scar tattoo to remind me. The Twins wanted their druids to suffer through pain.
        *if sex = "female"
            The scar tattoo of the Twins on my chest itches as I think of it. It never ceases to remind me of the time I screamed my lungs out as mother cut my skin. The cuts were deep. That's what the Twins demanded, she said.
            
            The Twins wanted their druids to suffer through pain.

        Both fear and jealousy raise their unpleasant heads within me but I quickly banish them. It feels ludicrous to believe everything ${q_he} says. However, the fact that we're talking in my head makes the situation more believable. "Then what?"

"They were worried about you. I received a blessing to help you."

It takes a moment to process ${q_his} words. The Twins not only spoke to ${q_him}, but gave ${q_him} their blessing.

Quinn nods. "I know it sounds weird."

"The blessing makes you able to lurk in my head?"

"Hey, I'm not [i]lurking[/i] here! I just recently learned how this stuff works anyway. Before that it was only projecting my thoughts to you. It was difficult to control them."

I sit down, and almost wonder why a chair materialized behind me. It's my mind, I suppose that's to be expected. Besides, that's the least weird thing in this situation. 

Quinn got the blessing of the Twins to help me. That is why ${q_he}'s now in my head. If I repeat it, maybe it would make more sense.

Quinn's chirpy voice reaches me in my musings: "Do you want the change of scenery? We could go to the grove."

"No need—" But before I can answer, it's almost as if a massive canvas falls in front of me, all around me, changing the landscape into a lush grove.

Not just any grove. [i]My[/i] grove. Exactly how I remembered it. Before they burnt it all.

I want to be happy to see it all again, as if I'm there. 

But it's not there. It's just a memory. Besides…

Quinn gives me a worried look, as if waiting for a sentencing to come.

*choice
    #It's definitely high time to freak out. $!{q_he}'s clearly a demon, meant to trick me.
        *set q_name "'Quinn'"
        *set ch3_quinn_demon true
        *goto ch3_quinn_demon
    #I don't believe a thing ${q_he} says. I will, however, play along for now.
        *set ch3_quinn_uh_huh_sure true
        *goto ch3_quinn_uh_huh_sure
    #This might be the best news I've gotten since I left. The Twins want to help me and they sent ${q_him} to aid me.
        *set ch3_quinn_yay true
        *goto quinn_yay
    #I really don't know how to react to the news. So I merely give ${q_him} a nod. Maybe I'm hallucinating, maybe this is a dream. Maybe I'll just wait for my mind to wake up.
        *set ch3_quinn_wtf true
        *goto quinn_wtf2
    #Why did ${q_he} get the blessing but not me? Everything I've ever done was to please the Twins and they just ignored me. They chose to give their blessing to ${q_him}?
        *set ch3_quinn_angry true
        *goto quinn_angry 
    
*label quinn_angry
Anger rises its head within me. It's coated with jealousy. But isn't it only natural to be angry about this? It was supposed to be me. I'm their druid, not ${q_him}.

"Why are you angry?" 

"Why did they choose you?" Why not me? I add without words. It's all too clear that that's what's bothering me. No need to say it out loud.

"I don't know why they didn't help you before you left." $!{q_he} looks deflated, as if ${q_he} truly doesn't know. After all, why would ${q_he}?  

"I'm sorry," ${q_he} whispers.

*fake_choice
    #"It's not your fault."
        I say as I try to swallow my resentment. It's not ${q_his} fault. This is between me and the Twins. I need to find out why they abandoned me.
        
        No. They haven't abandoned me. They just chose to show their affection in a different way. Yes.
    #Remain silent.
        I can't let go of my anger at this moment. This is just too much. Everything I've ever done was to please the Twins. And this is how they repay me? 
        
        I bite the inside of my cheek. I can't think like that. They don't owe me anything. That's what mother would say. You should serve them and not expect anything in return. It's your job to please them, not to be pleased. 
        
That's what I should tell myself so the bitterness won't eat my insides.
 
Quinn's next words are careful: "Do you want to listen how I met them?"
 
I take a deep breath and nod. "Sure."
*goto ch3_explanation

*label ch3_quinn_uh_huh_sure
I nod slowly and give ${q_him} a small smile, as if relieved that ${q_he}'s here.

However, Quinn doesn't seem to take the bait. $!{q_he} squints ${q_his} eyes at me. "It's alright if you don't trust me fully yet. I can understand that. I mean…" $!{q_he} gestures to the grove. "This is kind of crazy, right?"

I'll say. 

"I understand this is all too much to digest in one sitting. I truly understand your reaction. I didn't wish for it but we'll deal with it."

I squint my eyes at ${q_him} as a crow caws in the distance.

"I'm not your enemy. The ones outside are your enemies. We would be risking your life if we started to doubt each other. I want to help you. So can you humor me and listen to my encounter with the Twins?"

As much as it pains to admit it, ${q_he}'s right. Even if I'm not sure what the situation with Quinn is, I can't start panicking when there's so much on stake.

"Fine. Speak."
*goto ch3_explanation

*label ch3_quinn_demon
"Back off, demon!" I shout at ${q_him}. Why would I believe anything ${q_he} says? $!{q_he}'s been torturing me for weeks, never bothering to tell me that it's ${q_him}.

${q_name}'s eyes widen at the words. "Hey, I'm not—" $!{q_he} stops ${q_his} words and shakes his head. "You're not going to believe my word, are you? How can I convince you?"

"You can start by leaving my head at this instance."

"But we can talk privately here."

"Why would I want to talk privately to demons?"

${q_name} nods with pursed lips. "That's a good point. Well…" $!{q_he} sits on a cloud of moss with ${q_his} jaw resting on his hands. It's an uncannily familiar sight in this environment. 

"Can I… tell you something only I would know?"

"You're in my head. I'm sure you have access to my memories. I don't know how this stuff works and I'm not taking any chances."

"That is quite a logical way of thinking, I suppose. Well." $!{q_he} sighs as if I'm the troublemaker here. "I really didn't think you'd react this harshly."

"Did you think that I'd just welcome this all with open arms, thank the Twins, hug you, and offer you a beer?"

"Exactly like that! Are you sure you're not the one reading my thoughts?"

"This is not nearly as funny as you make it out to be." At least that side is compatible with the Quinn I know. However, maybe the demon is mimicking ${q_him}. It's horrendously convincing, if that's what this is. But how is ${q_he} taking control of Quinn's body? I've never encountered a demon before, I didn't even know they existed. 

${q_name} remains silent as these thoughts run through my head. Can ${q_he} read them all? A cold shiver runs through me.

"I understand this is all too much to digest in one sitting. I truly understand your reaction. I didn't wish for it but we'll deal with it."

I squint my eyes at ${q_him} as a crow caws in the distance.

"I'm not your enemy. The ones outside are your enemies. We would be risking your life if we started to doubt each other. I want to help you. So can you humor me and listen to my encounter with the Twins?"

As much as it pains to admit it, ${q_he}'s right. Even if I'm not sure what the situation with Quinn is, I can't start panicking when there's so much on stake.

"Fine. Speak."
*goto ch3_explanation

*label quinn_yay
"The Twins… spoke to you. They want to help me?"

"Yes."

A violent surge of happiness runs through me. I knew it. I knew they wouldn't leave me alone! I knew they would help me, I just knew it. All those years, all that pain mother made me endure in order to please the Twins, it wasn't in vain. They were watching.

However, there's that one question that keeps plaguing my mind. "Why would they give the blessing to you and not me?"

"You were in a hurry to leave. Besides, I had to…" $!{q_he} shifts ${q_his} weight from one foot to another before resuming the sentence. "I had to do a lot of stuff to make this happen. They didn't just give it to me freely."

This doesn't sound good. "Stuff?"

"You know… The gods don't spare you a glance if you don't offer them something."

"What did you give to them?"

$!{q_he} grimaces and looks away. "I will explain later. Please don't think I don't trust you or anything, I just don't want to talk about it."

Quinn's features quickly brighten as I nod. "But never mind that! The most important thing is that I'm here to help you. And boy, can I help you." $!{q_he} gives me a so familiar cheeky grin.
*goto ch3_explanation

*label quinn_wtf2
I nod and look around the grove. It's incredibly realistic. The scent is the same, it's late spring. My favorite season. It's the time when the lilacs bloom. It's the time when you know that the whole summer is still ahead of you, the warmth and joy it brings.

Quinn's gaze weighs heavy on my skin. I quickly look at ${q_him} from the corner of my eye. $!{q_he} stares at me with intensity I've never seen ${q_him} express before. 

Then, ${q_he} finally says: "You're not going to say anything about the news?"

I shrug and keep taking in the familiarity of the grove as long as I can. It's wonderful to be here, even if it's a memory. It's so life-like. "No. Not really."

"This is… weird. I mean, I made you doubt your sanity."

"I'm still very much doubting it. I guess I'm waiting to wake up."

"Alright… Can you humor me in the meantime and let me tell you about the Twins and the blessing?"

"I don't see why not."
*goto ch3_explanation
*label ch3_explanation
$!{q_he} walks to a tree and leans against it, looking at the clear blue sky. "The Twins appeared to my in my dreams. They told me that I should leave and help you and they would give me a blessing to do so. I didn't know what they were going to give me. Then I woke up and I realized that I could read minds."

"Everyone's minds?"

"Uh-huh. It was daunting at first. I don't just hear them all at once, I really have to concentrate on the person before I can hear anything."

"What else can you do?"

"I'm not exactly sure yet. I've been experimenting with these things."

"Why didn't you tell me sooner?"
 
"Would you have believed me?"
        
"Probably not, but that's a poor excuse. You could've said something."
        
"I didn't know how to speak directly to you. I was just echoing my thoughts, it was difficult."

*if antivoice
    "You made me think that I was paralyzed. I was terrified."
    
    $!{q_he} grimaces. "I'm really sorry. It was a side effect I didn't see coming. I know this isn't a good excuse but I'm still new to this."
    
    "You could just kill me by accident and claim it's because you're new to this."
    
    "No!" $!{q_he} shouts and my body jumps at the intensity and volume of it. $!{q_he} bites ${q_his} lip before continuing. "I would never do that to you. I'm being careful."
    
"Can you trust me?"

*fake_choice
    #"I want to trust you."
        *set quinn_wannatrust true
        This is all still fresh and new, how could I possibly fully trust ${q_him}? But I want to. The familiarity of ${q_his} features makes me unable to completely distrust ${q_him}. 
        
        $!{q_he}'s the only one I've got left from home.
        
        The smile ${q_he} gives me lacks any humor nor cheer, there's only relief. "Thank you. I will be worthy of your trust."
    #"No."
        *set quinn_nope_begone true
        How could I? $!{q_he} waited so long before telling me, ${q_he} made me doubt my sanity. $!{q_he}'s been sketchy this whole time, I could never fully trust ${q_him}.
            
        $!{q_he} grimaces. "I'm really sorry for what I did. I will make this up to you. I promise."
            
        I'm not sure what to think of such promise. 
    #"I'm not sure."
        *set quinn_hmm true
        This is all still fresh and new, how could I possibly fully either trust or distrust ${q_him}? The familiarity of ${q_his} features makes me unable to completely distrust ${q_him}. 
        
        $!{q_he}'s the only one I've got left from home.
         
        The smile ${q_he} gives me lacks any humor nor cheer, there's only relief. "Thank you. Thank you for not fully dismissing me. I will make this up to you. I promise."
    *selectable_if (ch3_quinn_demon) #"I still think you're a demon."
        *set quinn_yup_demon true
        "I understand that. I would probably think that, too, if I were you."

Quinn claps ${q_his} hands and smiles. "It's time to wake up. They must think you're dead or something."

Before I can answer, my mind is violently yanked back into another dimension. 

The reality.

*page_break
With my mind still in shambles, I try to gather my surroundings. Different voices. 

"Did you beat him unconscious?" Threatening, demanding.

"No, Lord Centurion! The little shit just fell over before I could do anything, I swear—"

"Hati! Can you hear me?" Pleading. I know that voice.

I open my eyes to find…
*fake_choice
    #Niall
        *set ch3_wakeup_niall true
        …looking at me.
        
        Why is he here? Why is that worrying gaze targeted at me, as if he cared? His eyes lighten up as they meet with mine, following with a smile. That stupid smile. I have bigger things to worry about than his stupid, worrying smile that makes two distinct dimples appear on his cheeks.
        
        "Hati, are you alright?" he says again, waiting for my response.
        
        "I'm… fine?" I'm not sure if I am, but I won't be telling him that. What just happened? Where's Quinn?
        
        Niall offers me his hand before I can process the racing thoughts further. 
        
        With some hesitation and my mind still foggy I take the hand he's offering. It takes little to no effort on his part to help me back up, his grip tight and firm. His hands are smooth, even if they're hands of a soldier. The warmth lingers on my skin even after he lets go.
                
        "Thank you."
                
        "Of course. Are you—" He stops himself before asking the same thing he's been asking me all this time. "Um. Did you hit your head?" He asks instead.
                
        "No, thank you."
                
        Before he can answer, a familiar voice interrupts:
                
        "Get him to the doctor if he's feeling ill."
    #Marcus
        *set ch3_wakeup_marcus true
        …looking at me.
        
        'No,' I almost say tiredly at his face. Why must it be you? Why am I waking up to your stupid face? My thoughts must've showed in my features since he gives me a wide, nasty grin. I wish I had the strength to punch it out of his face, but my arms are as heavy as my mind is foggy.
        
        Then, the realization over what just happened overcomes me. Was that just a dream? Where's Quinn?
        
        "Taking a nap there, soldier?" Marcus interrupts me again. This time I'm almost grateful for it. I really don't know what to think.
        
        "Yes, Lord Centurion." I get up on my own, not waiting for him to help me. Dizziness threatens to take over me and I misstep. Marcus takes a small step towards me but halts his movement after I give him the nastiest glare I can manage. 
        
        Don't touch me.
        
        "You're not going to faint on me again? His mocking concern isn't lost on me, but he follows it with a little more serious recommendation: "Go and see the doctor."
    #Camilla
        *set ch3_wakeup_camilla true
        …looking at me. Her face is bordering on bored. As if she really didn't want to be here looking at my face. I certainly didn't ask her to be here, thank you very much. 
        
        But for some reason she is there.
        
        "He seems fine," she says before asking me nor helping me up.
        
        "Thank you for your assessment, mother dearest," Marcus says with a mocking smile before turning his gaze to me. Camilla scoffs but says nothing.
               
        "You done taking a nap soldier? Can you get up?"
        
        I nod and quickly get up on my own, before he has a chance to try to help me. It's almost too fast for my foggy mind and heavy limbs, but I manage to keep myself from falling. By the time I gather my thoughts, Camilla is already gone, as if she was never here.
        
        "You need to go to the doctor."
    #Tinsae
        *set ch3_wakeup_tinsae true
        …looking at me. Her features are as calming as ever, the softness of her gaze relaxes my muscles despite the fact that I'm lying in the mud. As we're watching each other longer, the worry on her features almost makes me ask what's wrong. Then I realize it's because of me. Because I'm still lying flat on the ground.
        
        My eyes widen. What did I see? Where's Quinn?
        
        "Hati? Are you alright?" She repeats the question, forcing me to focus on her instead of my head.
        
        "My lady, just leave the little brat on the ground if he's not feeling like getting up." The voice of Marcus. "Soldier, don't make me kick you in the shin. Go and see the doctor if you're not feeling well."
        
"I'm fine, Lord Centurion." I don't need any more added attention. I really just want to bury myself in bed and stay there.

"You sure?"

"Yes, Lord Centurion."

He squints. 

*if marcus_voices
    "I insist."
    
    His scrutinizing gaze makes me bite my lip for a mere moment. He hasn't forgotten about the voices I told him. "Yes, Lord Centurion."

*if not(marcus_voices)
    "Fine. Dismissed."
    
    I sigh in relief. I don't need him to harass me any further now.
    
*if niall_voices
    "Wait!" Niall yelps at me before I have time to leave. "You should go and see the doctor."
    
    I frown, but Niall merely shakes his head. "I'm serious. Just to see if there's something… he can do to help."
    
    "Fine."
    
Just as I'm about to leave, Quinn appears into my line of vision. $!{q_he} waves at me, as if it's just any other day. I'm too dizzy to wave back at ${q_him}, but ${q_he} seems to pay no mind. Instead, ${q_he} gives me a wink and a mischievous grin.

As ${q_he} always does.
*goto_scene chapter_4